blob: a82a76d9e0018e0b6d70cc137c2105b549059aed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
// Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
// Copyright (C) INRIA, Serge Steer
// Copyright (C) 2010 - DIGITEO - Michael Baudin
// Copyright (C) DIGITEO - 2011 - Allan CORNET
//
// This file must be used under the terms of the CeCILL.
// This source file is licensed as described in the file COPYING, which
// you should have received as part of this distribution. The terms
// are also available at
// http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
function y = tand(x)
// Tangent of x in degrees.
// tand(x) = tan(x*%pi/180) in the mathematical sense
// But floating point numbers behave differently.
// For example, tand(180) = 0 while tan(pi) = -1.225D-16
rhs = argn(2);
if rhs <> 1 then
error(msprintf(gettext("%s: Wrong number of input argument(s): %d expected.\n"),"tand", 1));
end
if type(x)<>1 | ~isreal(x) then
error(msprintf(gettext("%s: Wrong type for input argument #%d: Real matrix expected.\n"),"tand",1));
end
// Argument reduction toward [-90,90[
n = round(x / 180);
x = x - n * 180;
y = tan(%pi/180*x);
// Set all singular points to nan
m = pmodulo(x + 90, 180);
y(m == 0) = %nan;
endfunction
|
