Moving lapack to right place

1 files changed, 0 insertions, 177 deletions

diff --git a/src/lib/lapack/dpptrf.f b/src/lib/lapack/dpptrf.f
deleted file mode 100644
index a5e2a596..00000000
--- a/src/lib/lapack/dpptrf.f
+++ /dev/null
@@ -1,177 +0,0 @@
-      SUBROUTINE DPPTRF( UPLO, N, AP, INFO )
-*
-*  -- LAPACK routine (version 3.1) --
-*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
-*     November 2006
-*
-*     .. Scalar Arguments ..
-      CHARACTER          UPLO
-      INTEGER            INFO, N
-*     ..
-*     .. Array Arguments ..
-      DOUBLE PRECISION   AP( * )
-*     ..
-*
-*  Purpose
-*  =======
-*
-*  DPPTRF computes the Cholesky factorization of a real symmetric
-*  positive definite matrix A stored in packed format.
-*
-*  The factorization has the form
-*     A = U**T * U,  if UPLO = 'U', or
-*     A = L  * L**T,  if UPLO = 'L',
-*  where U is an upper triangular matrix and L is lower triangular.
-*
-*  Arguments
-*  =========
-*
-*  UPLO    (input) CHARACTER*1
-*          = 'U':  Upper triangle of A is stored;
-*          = 'L':  Lower triangle of A is stored.
-*
-*  N       (input) INTEGER
-*          The order of the matrix A.  N >= 0.
-*
-*  AP      (input/output) DOUBLE PRECISION array, dimension (N*(N+1)/2)
-*          On entry, the upper or lower triangle of the symmetric matrix
-*          A, packed columnwise in a linear array.  The j-th column of A
-*          is stored in the array AP as follows:
-*          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
-*          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
-*          See below for further details.
-*
-*          On exit, if INFO = 0, the triangular factor U or L from the
-*          Cholesky factorization A = U**T*U or A = L*L**T, in the same
-*          storage format as A.
-*
-*  INFO    (output) INTEGER
-*          = 0:  successful exit
-*          < 0:  if INFO = -i, the i-th argument had an illegal value
-*          > 0:  if INFO = i, the leading minor of order i is not
-*                positive definite, and the factorization could not be
-*                completed.
-*
-*  Further Details
-*  ======= =======
-*
-*  The packed storage scheme is illustrated by the following example
-*  when N = 4, UPLO = 'U':
-*
-*  Two-dimensional storage of the symmetric matrix A:
-*
-*     a11 a12 a13 a14
-*         a22 a23 a24
-*             a33 a34     (aij = aji)
-*                 a44
-*
-*  Packed storage of the upper triangle of A:
-*
-*  AP = [ a11, a12, a22, a13, a23, a33, a14, a24, a34, a44 ]
-*
-*  =====================================================================
-*
-*     .. Parameters ..
-      DOUBLE PRECISION   ONE, ZERO
-      PARAMETER          ( ONE = 1.0D+0, ZERO = 0.0D+0 )
-*     ..
-*     .. Local Scalars ..
-      LOGICAL            UPPER
-      INTEGER            J, JC, JJ
-      DOUBLE PRECISION   AJJ
-*     ..
-*     .. External Functions ..
-      LOGICAL            LSAME
-      DOUBLE PRECISION   DDOT
-      EXTERNAL           LSAME, DDOT
-*     ..
-*     .. External Subroutines ..
-      EXTERNAL           DSCAL, DSPR, DTPSV, XERBLA
-*     ..
-*     .. Intrinsic Functions ..
-      INTRINSIC          SQRT
-*     ..
-*     .. Executable Statements ..
-*
-*     Test the input parameters.
-*
-      INFO = 0
-      UPPER = LSAME( UPLO, 'U' )
-      IF( .NOT.UPPER .AND. .NOT.LSAME( UPLO, 'L' ) ) THEN
-         INFO = -1
-      ELSE IF( N.LT.0 ) THEN
-         INFO = -2
-      END IF
-      IF( INFO.NE.0 ) THEN
-         CALL XERBLA( 'DPPTRF', -INFO )
-         RETURN
-      END IF
-*
-*     Quick return if possible
-*
-      IF( N.EQ.0 )
-     $   RETURN
-*
-      IF( UPPER ) THEN
-*
-*        Compute the Cholesky factorization A = U'*U.
-*
-         JJ = 0
-         DO 10 J = 1, N
-            JC = JJ + 1
-            JJ = JJ + J
-*
-*           Compute elements 1:J-1 of column J.
-*
-            IF( J.GT.1 )
-     $         CALL DTPSV( 'Upper', 'Transpose', 'Non-unit', J-1, AP,
-     $                     AP( JC ), 1 )
-*
-*           Compute U(J,J) and test for non-positive-definiteness.
-*
-            AJJ = AP( JJ ) - DDOT( J-1, AP( JC ), 1, AP( JC ), 1 )
-            IF( AJJ.LE.ZERO ) THEN
-               AP( JJ ) = AJJ
-               GO TO 30
-            END IF
-            AP( JJ ) = SQRT( AJJ )
-   10    CONTINUE
-      ELSE
-*
-*        Compute the Cholesky factorization A = L*L'.
-*
-         JJ = 1
-         DO 20 J = 1, N
-*
-*           Compute L(J,J) and test for non-positive-definiteness.
-*
-            AJJ = AP( JJ )
-            IF( AJJ.LE.ZERO ) THEN
-               AP( JJ ) = AJJ
-               GO TO 30
-            END IF
-            AJJ = SQRT( AJJ )
-            AP( JJ ) = AJJ
-*
-*           Compute elements J+1:N of column J and update the trailing
-*           submatrix.
-*
-            IF( J.LT.N ) THEN
-               CALL DSCAL( N-J, ONE / AJJ, AP( JJ+1 ), 1 )
-               CALL DSPR( 'Lower', N-J, -ONE, AP( JJ+1 ), 1,
-     $                    AP( JJ+N-J+1 ) )
-               JJ = JJ + N - J + 1
-            END IF
-   20    CONTINUE
-      END IF
-      GO TO 40
-*
-   30 CONTINUE
-      INFO = J
-*
-   40 CONTINUE
-      RETURN
-*
-*     End of DPPTRF
-*
-      END