Moving lapack to right place

1 files changed, 0 insertions, 640 deletions

diff --git a/src/lib/lapack/dlaqr4.f b/src/lib/lapack/dlaqr4.f
deleted file mode 100644
index 8692e7f9..00000000
--- a/src/lib/lapack/dlaqr4.f
+++ /dev/null
@@ -1,640 +0,0 @@
-      SUBROUTINE DLAQR4( WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI,
-     $                   ILOZ, IHIZ, Z, LDZ, WORK, LWORK, INFO )
-*
-*  -- LAPACK auxiliary routine (version 3.1) --
-*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
-*     November 2006
-*
-*     .. Scalar Arguments ..
-      INTEGER            IHI, IHIZ, ILO, ILOZ, INFO, LDH, LDZ, LWORK, N
-      LOGICAL            WANTT, WANTZ
-*     ..
-*     .. Array Arguments ..
-      DOUBLE PRECISION   H( LDH, * ), WI( * ), WORK( * ), WR( * ),
-     $                   Z( LDZ, * )
-*     ..
-*
-*     This subroutine implements one level of recursion for DLAQR0.
-*     It is a complete implementation of the small bulge multi-shift
-*     QR algorithm.  It may be called by DLAQR0 and, for large enough
-*     deflation window size, it may be called by DLAQR3.  This
-*     subroutine is identical to DLAQR0 except that it calls DLAQR2
-*     instead of DLAQR3.
-*
-*     Purpose
-*     =======
-*
-*     DLAQR4 computes the eigenvalues of a Hessenberg matrix H
-*     and, optionally, the matrices T and Z from the Schur decomposition
-*     H = Z T Z**T, where T is an upper quasi-triangular matrix (the
-*     Schur form), and Z is the orthogonal matrix of Schur vectors.
-*
-*     Optionally Z may be postmultiplied into an input orthogonal
-*     matrix Q so that this routine can give the Schur factorization
-*     of a matrix A which has been reduced to the Hessenberg form H
-*     by the orthogonal matrix Q:  A = Q*H*Q**T = (QZ)*T*(QZ)**T.
-*
-*     Arguments
-*     =========
-*
-*     WANTT   (input) LOGICAL
-*          = .TRUE. : the full Schur form T is required;
-*          = .FALSE.: only eigenvalues are required.
-*
-*     WANTZ   (input) LOGICAL
-*          = .TRUE. : the matrix of Schur vectors Z is required;
-*          = .FALSE.: Schur vectors are not required.
-*
-*     N     (input) INTEGER
-*           The order of the matrix H.  N .GE. 0.
-*
-*     ILO   (input) INTEGER
-*     IHI   (input) INTEGER
-*           It is assumed that H is already upper triangular in rows
-*           and columns 1:ILO-1 and IHI+1:N and, if ILO.GT.1,
-*           H(ILO,ILO-1) is zero. ILO and IHI are normally set by a
-*           previous call to DGEBAL, and then passed to DGEHRD when the
-*           matrix output by DGEBAL is reduced to Hessenberg form.
-*           Otherwise, ILO and IHI should be set to 1 and N,
-*           respectively.  If N.GT.0, then 1.LE.ILO.LE.IHI.LE.N.
-*           If N = 0, then ILO = 1 and IHI = 0.
-*
-*     H     (input/output) DOUBLE PRECISION array, dimension (LDH,N)
-*           On entry, the upper Hessenberg matrix H.
-*           On exit, if INFO = 0 and WANTT is .TRUE., then H contains
-*           the upper quasi-triangular matrix T from the Schur
-*           decomposition (the Schur form); 2-by-2 diagonal blocks
-*           (corresponding to complex conjugate pairs of eigenvalues)
-*           are returned in standard form, with H(i,i) = H(i+1,i+1)
-*           and H(i+1,i)*H(i,i+1).LT.0. If INFO = 0 and WANTT is
-*           .FALSE., then the contents of H are unspecified on exit.
-*           (The output value of H when INFO.GT.0 is given under the
-*           description of INFO below.)
-*
-*           This subroutine may explicitly set H(i,j) = 0 for i.GT.j and
-*           j = 1, 2, ... ILO-1 or j = IHI+1, IHI+2, ... N.
-*
-*     LDH   (input) INTEGER
-*           The leading dimension of the array H. LDH .GE. max(1,N).
-*
-*     WR    (output) DOUBLE PRECISION array, dimension (IHI)
-*     WI    (output) DOUBLE PRECISION array, dimension (IHI)
-*           The real and imaginary parts, respectively, of the computed
-*           eigenvalues of H(ILO:IHI,ILO:IHI) are stored WR(ILO:IHI)
-*           and WI(ILO:IHI). If two eigenvalues are computed as a
-*           complex conjugate pair, they are stored in consecutive
-*           elements of WR and WI, say the i-th and (i+1)th, with
-*           WI(i) .GT. 0 and WI(i+1) .LT. 0. If WANTT is .TRUE., then
-*           the eigenvalues are stored in the same order as on the
-*           diagonal of the Schur form returned in H, with
-*           WR(i) = H(i,i) and, if H(i:i+1,i:i+1) is a 2-by-2 diagonal
-*           block, WI(i) = sqrt(-H(i+1,i)*H(i,i+1)) and
-*           WI(i+1) = -WI(i).
-*
-*     ILOZ     (input) INTEGER
-*     IHIZ     (input) INTEGER
-*           Specify the rows of Z to which transformations must be
-*           applied if WANTZ is .TRUE..
-*           1 .LE. ILOZ .LE. ILO; IHI .LE. IHIZ .LE. N.
-*
-*     Z     (input/output) DOUBLE PRECISION array, dimension (LDZ,IHI)
-*           If WANTZ is .FALSE., then Z is not referenced.
-*           If WANTZ is .TRUE., then Z(ILO:IHI,ILOZ:IHIZ) is
-*           replaced by Z(ILO:IHI,ILOZ:IHIZ)*U where U is the
-*           orthogonal Schur factor of H(ILO:IHI,ILO:IHI).
-*           (The output value of Z when INFO.GT.0 is given under
-*           the description of INFO below.)
-*
-*     LDZ   (input) INTEGER
-*           The leading dimension of the array Z.  if WANTZ is .TRUE.
-*           then LDZ.GE.MAX(1,IHIZ).  Otherwize, LDZ.GE.1.
-*
-*     WORK  (workspace/output) DOUBLE PRECISION array, dimension LWORK
-*           On exit, if LWORK = -1, WORK(1) returns an estimate of
-*           the optimal value for LWORK.
-*
-*     LWORK (input) INTEGER
-*           The dimension of the array WORK.  LWORK .GE. max(1,N)
-*           is sufficient, but LWORK typically as large as 6*N may
-*           be required for optimal performance.  A workspace query
-*           to determine the optimal workspace size is recommended.
-*
-*           If LWORK = -1, then DLAQR4 does a workspace query.
-*           In this case, DLAQR4 checks the input parameters and
-*           estimates the optimal workspace size for the given
-*           values of N, ILO and IHI.  The estimate is returned
-*           in WORK(1).  No error message related to LWORK is
-*           issued by XERBLA.  Neither H nor Z are accessed.
-*
-*
-*     INFO  (output) INTEGER
-*             =  0:  successful exit
-*           .GT. 0:  if INFO = i, DLAQR4 failed to compute all of
-*                the eigenvalues.  Elements 1:ilo-1 and i+1:n of WR
-*                and WI contain those eigenvalues which have been
-*                successfully computed.  (Failures are rare.)
-*
-*                If INFO .GT. 0 and WANT is .FALSE., then on exit,
-*                the remaining unconverged eigenvalues are the eigen-
-*                values of the upper Hessenberg matrix rows and
-*                columns ILO through INFO of the final, output
-*                value of H.
-*
-*                If INFO .GT. 0 and WANTT is .TRUE., then on exit
-*
-*           (*)  (initial value of H)*U  = U*(final value of H)
-*
-*                where U is an orthogonal matrix.  The final
-*                value of H is upper Hessenberg and quasi-triangular
-*                in rows and columns INFO+1 through IHI.
-*
-*                If INFO .GT. 0 and WANTZ is .TRUE., then on exit
-*
-*                  (final value of Z(ILO:IHI,ILOZ:IHIZ)
-*                   =  (initial value of Z(ILO:IHI,ILOZ:IHIZ)*U
-*
-*                where U is the orthogonal matrix in (*) (regard-
-*                less of the value of WANTT.)
-*
-*                If INFO .GT. 0 and WANTZ is .FALSE., then Z is not
-*                accessed.
-*
-*     ================================================================
-*     Based on contributions by
-*        Karen Braman and Ralph Byers, Department of Mathematics,
-*        University of Kansas, USA
-*
-*     ================================================================
-*     References:
-*       K. Braman, R. Byers and R. Mathias, The Multi-Shift QR
-*       Algorithm Part I: Maintaining Well Focused Shifts, and Level 3
-*       Performance, SIAM Journal of Matrix Analysis, volume 23, pages
-*       929--947, 2002.
-*
-*       K. Braman, R. Byers and R. Mathias, The Multi-Shift QR
-*       Algorithm Part II: Aggressive Early Deflation, SIAM Journal
-*       of Matrix Analysis, volume 23, pages 948--973, 2002.
-*
-*     ================================================================
-*     .. Parameters ..
-*
-*     ==== Matrices of order NTINY or smaller must be processed by
-*     .    DLAHQR because of insufficient subdiagonal scratch space.
-*     .    (This is a hard limit.) ====
-*
-*     ==== Exceptional deflation windows:  try to cure rare
-*     .    slow convergence by increasing the size of the
-*     .    deflation window after KEXNW iterations. =====
-*
-*     ==== Exceptional shifts: try to cure rare slow convergence
-*     .    with ad-hoc exceptional shifts every KEXSH iterations.
-*     .    The constants WILK1 and WILK2 are used to form the
-*     .    exceptional shifts. ====
-*
-      INTEGER            NTINY
-      PARAMETER          ( NTINY = 11 )
-      INTEGER            KEXNW, KEXSH
-      PARAMETER          ( KEXNW = 5, KEXSH = 6 )
-      DOUBLE PRECISION   WILK1, WILK2
-      PARAMETER          ( WILK1 = 0.75d0, WILK2 = -0.4375d0 )
-      DOUBLE PRECISION   ZERO, ONE
-      PARAMETER          ( ZERO = 0.0d0, ONE = 1.0d0 )
-*     ..
-*     .. Local Scalars ..
-      DOUBLE PRECISION   AA, BB, CC, CS, DD, SN, SS, SWAP
-      INTEGER            I, INF, IT, ITMAX, K, KACC22, KBOT, KDU, KS,
-     $                   KT, KTOP, KU, KV, KWH, KWTOP, KWV, LD, LS,
-     $                   LWKOPT, NDFL, NH, NHO, NIBBLE, NMIN, NS, NSMAX,
-     $                   NSR, NVE, NW, NWMAX, NWR
-      LOGICAL            NWINC, SORTED
-      CHARACTER          JBCMPZ*2
-*     ..
-*     .. External Functions ..
-      INTEGER            ILAENV
-      EXTERNAL           ILAENV
-*     ..
-*     .. Local Arrays ..
-      DOUBLE PRECISION   ZDUM( 1, 1 )
-*     ..
-*     .. External Subroutines ..
-      EXTERNAL           DLACPY, DLAHQR, DLANV2, DLAQR2, DLAQR5
-*     ..
-*     .. Intrinsic Functions ..
-      INTRINSIC          ABS, DBLE, INT, MAX, MIN, MOD
-*     ..
-*     .. Executable Statements ..
-      INFO = 0
-*
-*     ==== Quick return for N = 0: nothing to do. ====
-*
-      IF( N.EQ.0 ) THEN
-         WORK( 1 ) = ONE
-         RETURN
-      END IF
-*
-*     ==== Set up job flags for ILAENV. ====
-*
-      IF( WANTT ) THEN
-         JBCMPZ( 1: 1 ) = 'S'
-      ELSE
-         JBCMPZ( 1: 1 ) = 'E'
-      END IF
-      IF( WANTZ ) THEN
-         JBCMPZ( 2: 2 ) = 'V'
-      ELSE
-         JBCMPZ( 2: 2 ) = 'N'
-      END IF
-*
-*     ==== Tiny matrices must use DLAHQR. ====
-*
-      IF( N.LE.NTINY ) THEN
-*
-*        ==== Estimate optimal workspace. ====
-*
-         LWKOPT = 1
-         IF( LWORK.NE.-1 )
-     $      CALL DLAHQR( WANTT, WANTZ, N, ILO, IHI, H, LDH, WR, WI,
-     $                   ILOZ, IHIZ, Z, LDZ, INFO )
-      ELSE
-*
-*        ==== Use small bulge multi-shift QR with aggressive early
-*        .    deflation on larger-than-tiny matrices. ====
-*
-*        ==== Hope for the best. ====
-*
-         INFO = 0
-*
-*        ==== NWR = recommended deflation window size.  At this
-*        .    point,  N .GT. NTINY = 11, so there is enough
-*        .    subdiagonal workspace for NWR.GE.2 as required.
-*        .    (In fact, there is enough subdiagonal space for
-*        .    NWR.GE.3.) ====
-*
-         NWR = ILAENV( 13, 'DLAQR4', JBCMPZ, N, ILO, IHI, LWORK )
-         NWR = MAX( 2, NWR )
-         NWR = MIN( IHI-ILO+1, ( N-1 ) / 3, NWR )
-         NW = NWR
-*
-*        ==== NSR = recommended number of simultaneous shifts.
-*        .    At this point N .GT. NTINY = 11, so there is at
-*        .    enough subdiagonal workspace for NSR to be even
-*        .    and greater than or equal to two as required. ====
-*
-         NSR = ILAENV( 15, 'DLAQR4', JBCMPZ, N, ILO, IHI, LWORK )
-         NSR = MIN( NSR, ( N+6 ) / 9, IHI-ILO )
-         NSR = MAX( 2, NSR-MOD( NSR, 2 ) )
-*
-*        ==== Estimate optimal workspace ====
-*
-*        ==== Workspace query call to DLAQR2 ====
-*
-         CALL DLAQR2( WANTT, WANTZ, N, ILO, IHI, NWR+1, H, LDH, ILOZ,
-     $                IHIZ, Z, LDZ, LS, LD, WR, WI, H, LDH, N, H, LDH,
-     $                N, H, LDH, WORK, -1 )
-*
-*        ==== Optimal workspace = MAX(DLAQR5, DLAQR2) ====
-*
-         LWKOPT = MAX( 3*NSR / 2, INT( WORK( 1 ) ) )
-*
-*        ==== Quick return in case of workspace query. ====
-*
-         IF( LWORK.EQ.-1 ) THEN
-            WORK( 1 ) = DBLE( LWKOPT )
-            RETURN
-         END IF
-*
-*        ==== DLAHQR/DLAQR0 crossover point ====
-*
-         NMIN = ILAENV( 12, 'DLAQR4', JBCMPZ, N, ILO, IHI, LWORK )
-         NMIN = MAX( NTINY, NMIN )
-*
-*        ==== Nibble crossover point ====
-*
-         NIBBLE = ILAENV( 14, 'DLAQR4', JBCMPZ, N, ILO, IHI, LWORK )
-         NIBBLE = MAX( 0, NIBBLE )
-*
-*        ==== Accumulate reflections during ttswp?  Use block
-*        .    2-by-2 structure during matrix-matrix multiply? ====
-*
-         KACC22 = ILAENV( 16, 'DLAQR4', JBCMPZ, N, ILO, IHI, LWORK )
-         KACC22 = MAX( 0, KACC22 )
-         KACC22 = MIN( 2, KACC22 )
-*
-*        ==== NWMAX = the largest possible deflation window for
-*        .    which there is sufficient workspace. ====
-*
-         NWMAX = MIN( ( N-1 ) / 3, LWORK / 2 )
-*
-*        ==== NSMAX = the Largest number of simultaneous shifts
-*        .    for which there is sufficient workspace. ====
-*
-         NSMAX = MIN( ( N+6 ) / 9, 2*LWORK / 3 )
-         NSMAX = NSMAX - MOD( NSMAX, 2 )
-*
-*        ==== NDFL: an iteration count restarted at deflation. ====
-*
-         NDFL = 1
-*
-*        ==== ITMAX = iteration limit ====
-*
-         ITMAX = MAX( 30, 2*KEXSH )*MAX( 10, ( IHI-ILO+1 ) )
-*
-*        ==== Last row and column in the active block ====
-*
-         KBOT = IHI
-*
-*        ==== Main Loop ====
-*
-         DO 80 IT = 1, ITMAX
-*
-*           ==== Done when KBOT falls below ILO ====
-*
-            IF( KBOT.LT.ILO )
-     $         GO TO 90
-*
-*           ==== Locate active block ====
-*
-            DO 10 K = KBOT, ILO + 1, -1
-               IF( H( K, K-1 ).EQ.ZERO )
-     $            GO TO 20
-   10       CONTINUE
-            K = ILO
-   20       CONTINUE
-            KTOP = K
-*
-*           ==== Select deflation window size ====
-*
-            NH = KBOT - KTOP + 1
-            IF( NDFL.LT.KEXNW .OR. NH.LT.NW ) THEN
-*
-*              ==== Typical deflation window.  If possible and
-*              .    advisable, nibble the entire active block.
-*              .    If not, use size NWR or NWR+1 depending upon
-*              .    which has the smaller corresponding subdiagonal
-*              .    entry (a heuristic). ====
-*
-               NWINC = .TRUE.
-               IF( NH.LE.MIN( NMIN, NWMAX ) ) THEN
-                  NW = NH
-               ELSE
-                  NW = MIN( NWR, NH, NWMAX )
-                  IF( NW.LT.NWMAX ) THEN
-                     IF( NW.GE.NH-1 ) THEN
-                        NW = NH
-                     ELSE
-                        KWTOP = KBOT - NW + 1
-                        IF( ABS( H( KWTOP, KWTOP-1 ) ).GT.
-     $                      ABS( H( KWTOP-1, KWTOP-2 ) ) )NW = NW + 1
-                     END IF
-                  END IF
-               END IF
-            ELSE
-*
-*              ==== Exceptional deflation window.  If there have
-*              .    been no deflations in KEXNW or more iterations,
-*              .    then vary the deflation window size.   At first,
-*              .    because, larger windows are, in general, more
-*              .    powerful than smaller ones, rapidly increase the
-*              .    window up to the maximum reasonable and possible.
-*              .    Then maybe try a slightly smaller window.  ====
-*
-               IF( NWINC .AND. NW.LT.MIN( NWMAX, NH ) ) THEN
-                  NW = MIN( NWMAX, NH, 2*NW )
-               ELSE
-                  NWINC = .FALSE.
-                  IF( NW.EQ.NH .AND. NH.GT.2 )
-     $               NW = NH - 1
-               END IF
-            END IF
-*
-*           ==== Aggressive early deflation:
-*           .    split workspace under the subdiagonal into
-*           .      - an nw-by-nw work array V in the lower
-*           .        left-hand-corner,
-*           .      - an NW-by-at-least-NW-but-more-is-better
-*           .        (NW-by-NHO) horizontal work array along
-*           .        the bottom edge,
-*           .      - an at-least-NW-but-more-is-better (NHV-by-NW)
-*           .        vertical work array along the left-hand-edge.
-*           .        ====
-*
-            KV = N - NW + 1
-            KT = NW + 1
-            NHO = ( N-NW-1 ) - KT + 1
-            KWV = NW + 2
-            NVE = ( N-NW ) - KWV + 1
-*
-*           ==== Aggressive early deflation ====
-*
-            CALL DLAQR2( WANTT, WANTZ, N, KTOP, KBOT, NW, H, LDH, ILOZ,
-     $                   IHIZ, Z, LDZ, LS, LD, WR, WI, H( KV, 1 ), LDH,
-     $                   NHO, H( KV, KT ), LDH, NVE, H( KWV, 1 ), LDH,
-     $                   WORK, LWORK )
-*
-*           ==== Adjust KBOT accounting for new deflations. ====
-*
-            KBOT = KBOT - LD
-*
-*           ==== KS points to the shifts. ====
-*
-            KS = KBOT - LS + 1
-*
-*           ==== Skip an expensive QR sweep if there is a (partly
-*           .    heuristic) reason to expect that many eigenvalues
-*           .    will deflate without it.  Here, the QR sweep is
-*           .    skipped if many eigenvalues have just been deflated
-*           .    or if the remaining active block is small.
-*
-            IF( ( LD.EQ.0 ) .OR. ( ( 100*LD.LE.NW*NIBBLE ) .AND. ( KBOT-
-     $          KTOP+1.GT.MIN( NMIN, NWMAX ) ) ) ) THEN
-*
-*              ==== NS = nominal number of simultaneous shifts.
-*              .    This may be lowered (slightly) if DLAQR2
-*              .    did not provide that many shifts. ====
-*
-               NS = MIN( NSMAX, NSR, MAX( 2, KBOT-KTOP ) )
-               NS = NS - MOD( NS, 2 )
-*
-*              ==== If there have been no deflations
-*              .    in a multiple of KEXSH iterations,
-*              .    then try exceptional shifts.
-*              .    Otherwise use shifts provided by
-*              .    DLAQR2 above or from the eigenvalues
-*              .    of a trailing principal submatrix. ====
-*
-               IF( MOD( NDFL, KEXSH ).EQ.0 ) THEN
-                  KS = KBOT - NS + 1
-                  DO 30 I = KBOT, MAX( KS+1, KTOP+2 ), -2
-                     SS = ABS( H( I, I-1 ) ) + ABS( H( I-1, I-2 ) )
-                     AA = WILK1*SS + H( I, I )
-                     BB = SS
-                     CC = WILK2*SS
-                     DD = AA
-                     CALL DLANV2( AA, BB, CC, DD, WR( I-1 ), WI( I-1 ),
-     $                            WR( I ), WI( I ), CS, SN )
-   30             CONTINUE
-                  IF( KS.EQ.KTOP ) THEN
-                     WR( KS+1 ) = H( KS+1, KS+1 )
-                     WI( KS+1 ) = ZERO
-                     WR( KS ) = WR( KS+1 )
-                     WI( KS ) = WI( KS+1 )
-                  END IF
-               ELSE
-*
-*                 ==== Got NS/2 or fewer shifts? Use DLAHQR
-*                 .    on a trailing principal submatrix to
-*                 .    get more. (Since NS.LE.NSMAX.LE.(N+6)/9,
-*                 .    there is enough space below the subdiagonal
-*                 .    to fit an NS-by-NS scratch array.) ====
-*
-                  IF( KBOT-KS+1.LE.NS / 2 ) THEN
-                     KS = KBOT - NS + 1
-                     KT = N - NS + 1
-                     CALL DLACPY( 'A', NS, NS, H( KS, KS ), LDH,
-     $                            H( KT, 1 ), LDH )
-                     CALL DLAHQR( .false., .false., NS, 1, NS,
-     $                            H( KT, 1 ), LDH, WR( KS ), WI( KS ),
-     $                            1, 1, ZDUM, 1, INF )
-                     KS = KS + INF
-*
-*                    ==== In case of a rare QR failure use
-*                    .    eigenvalues of the trailing 2-by-2
-*                    .    principal submatrix.  ====
-*
-                     IF( KS.GE.KBOT ) THEN
-                        AA = H( KBOT-1, KBOT-1 )
-                        CC = H( KBOT, KBOT-1 )
-                        BB = H( KBOT-1, KBOT )
-                        DD = H( KBOT, KBOT )
-                        CALL DLANV2( AA, BB, CC, DD, WR( KBOT-1 ),
-     $                               WI( KBOT-1 ), WR( KBOT ),
-     $                               WI( KBOT ), CS, SN )
-                        KS = KBOT - 1
-                     END IF
-                  END IF
-*
-                  IF( KBOT-KS+1.GT.NS ) THEN
-*
-*                    ==== Sort the shifts (Helps a little)
-*                    .    Bubble sort keeps complex conjugate
-*                    .    pairs together. ====
-*
-                     SORTED = .false.
-                     DO 50 K = KBOT, KS + 1, -1
-                        IF( SORTED )
-     $                     GO TO 60
-                        SORTED = .true.
-                        DO 40 I = KS, K - 1
-                           IF( ABS( WR( I ) )+ABS( WI( I ) ).LT.
-     $                         ABS( WR( I+1 ) )+ABS( WI( I+1 ) ) ) THEN
-                              SORTED = .false.
-*
-                              SWAP = WR( I )
-                              WR( I ) = WR( I+1 )
-                              WR( I+1 ) = SWAP
-*
-                              SWAP = WI( I )
-                              WI( I ) = WI( I+1 )
-                              WI( I+1 ) = SWAP
-                           END IF
-   40                   CONTINUE
-   50                CONTINUE
-   60                CONTINUE
-                  END IF
-*
-*                 ==== Shuffle shifts into pairs of real shifts
-*                 .    and pairs of complex conjugate shifts
-*                 .    assuming complex conjugate shifts are
-*                 .    already adjacent to one another. (Yes,
-*                 .    they are.)  ====
-*
-                  DO 70 I = KBOT, KS + 2, -2
-                     IF( WI( I ).NE.-WI( I-1 ) ) THEN
-*
-                        SWAP = WR( I )
-                        WR( I ) = WR( I-1 )
-                        WR( I-1 ) = WR( I-2 )
-                        WR( I-2 ) = SWAP
-*
-                        SWAP = WI( I )
-                        WI( I ) = WI( I-1 )
-                        WI( I-1 ) = WI( I-2 )
-                        WI( I-2 ) = SWAP
-                     END IF
-   70             CONTINUE
-               END IF
-*
-*              ==== If there are only two shifts and both are
-*              .    real, then use only one.  ====
-*
-               IF( KBOT-KS+1.EQ.2 ) THEN
-                  IF( WI( KBOT ).EQ.ZERO ) THEN
-                     IF( ABS( WR( KBOT )-H( KBOT, KBOT ) ).LT.
-     $                   ABS( WR( KBOT-1 )-H( KBOT, KBOT ) ) ) THEN
-                        WR( KBOT-1 ) = WR( KBOT )
-                     ELSE
-                        WR( KBOT ) = WR( KBOT-1 )
-                     END IF
-                  END IF
-               END IF
-*
-*              ==== Use up to NS of the the smallest magnatiude
-*              .    shifts.  If there aren't NS shifts available,
-*              .    then use them all, possibly dropping one to
-*              .    make the number of shifts even. ====
-*
-               NS = MIN( NS, KBOT-KS+1 )
-               NS = NS - MOD( NS, 2 )
-               KS = KBOT - NS + 1
-*
-*              ==== Small-bulge multi-shift QR sweep:
-*              .    split workspace under the subdiagonal into
-*              .    - a KDU-by-KDU work array U in the lower
-*              .      left-hand-corner,
-*              .    - a KDU-by-at-least-KDU-but-more-is-better
-*              .      (KDU-by-NHo) horizontal work array WH along
-*              .      the bottom edge,
-*              .    - and an at-least-KDU-but-more-is-better-by-KDU
-*              .      (NVE-by-KDU) vertical work WV arrow along
-*              .      the left-hand-edge. ====
-*
-               KDU = 3*NS - 3
-               KU = N - KDU + 1
-               KWH = KDU + 1
-               NHO = ( N-KDU+1-4 ) - ( KDU+1 ) + 1
-               KWV = KDU + 4
-               NVE = N - KDU - KWV + 1
-*
-*              ==== Small-bulge multi-shift QR sweep ====
-*
-               CALL DLAQR5( WANTT, WANTZ, KACC22, N, KTOP, KBOT, NS,
-     $                      WR( KS ), WI( KS ), H, LDH, ILOZ, IHIZ, Z,
-     $                      LDZ, WORK, 3, H( KU, 1 ), LDH, NVE,
-     $                      H( KWV, 1 ), LDH, NHO, H( KU, KWH ), LDH )
-            END IF
-*
-*           ==== Note progress (or the lack of it). ====
-*
-            IF( LD.GT.0 ) THEN
-               NDFL = 1
-            ELSE
-               NDFL = NDFL + 1
-            END IF
-*
-*           ==== End of main loop ====
-   80    CONTINUE
-*
-*        ==== Iteration limit exceeded.  Set INFO to show where
-*        .    the problem occurred and exit. ====
-*
-         INFO = KBOT
-   90    CONTINUE
-      END IF
-*
-*     ==== Return the optimal value of LWORK. ====
-*
-      WORK( 1 ) = DBLE( LWKOPT )
-*
-*     ==== End of DLAQR4 ====
-*
-      END