Moving lapack to right place

1 files changed, 0 insertions, 336 deletions

diff --git a/src/lib/lapack/dgerfs.f b/src/lib/lapack/dgerfs.f
deleted file mode 100644
index bada6e56..00000000
--- a/src/lib/lapack/dgerfs.f
+++ /dev/null
@@ -1,336 +0,0 @@
-      SUBROUTINE DGERFS( TRANS, N, NRHS, A, LDA, AF, LDAF, IPIV, B, LDB,
-     $                   X, LDX, FERR, BERR, WORK, IWORK, INFO )
-*
-*  -- LAPACK routine (version 3.1) --
-*     Univ. of Tennessee, Univ. of California Berkeley and NAG Ltd..
-*     November 2006
-*
-*     Modified to call DLACN2 in place of DLACON, 5 Feb 03, SJH.
-*
-*     .. Scalar Arguments ..
-      CHARACTER          TRANS
-      INTEGER            INFO, LDA, LDAF, LDB, LDX, N, NRHS
-*     ..
-*     .. Array Arguments ..
-      INTEGER            IPIV( * ), IWORK( * )
-      DOUBLE PRECISION   A( LDA, * ), AF( LDAF, * ), B( LDB, * ),
-     $                   BERR( * ), FERR( * ), WORK( * ), X( LDX, * )
-*     ..
-*
-*  Purpose
-*  =======
-*
-*  DGERFS improves the computed solution to a system of linear
-*  equations and provides error bounds and backward error estimates for
-*  the solution.
-*
-*  Arguments
-*  =========
-*
-*  TRANS   (input) CHARACTER*1
-*          Specifies the form of the system of equations:
-*          = 'N':  A * X = B     (No transpose)
-*          = 'T':  A**T * X = B  (Transpose)
-*          = 'C':  A**H * X = B  (Conjugate transpose = Transpose)
-*
-*  N       (input) INTEGER
-*          The order of the matrix A.  N >= 0.
-*
-*  NRHS    (input) INTEGER
-*          The number of right hand sides, i.e., the number of columns
-*          of the matrices B and X.  NRHS >= 0.
-*
-*  A       (input) DOUBLE PRECISION array, dimension (LDA,N)
-*          The original N-by-N matrix A.
-*
-*  LDA     (input) INTEGER
-*          The leading dimension of the array A.  LDA >= max(1,N).
-*
-*  AF      (input) DOUBLE PRECISION array, dimension (LDAF,N)
-*          The factors L and U from the factorization A = P*L*U
-*          as computed by DGETRF.
-*
-*  LDAF    (input) INTEGER
-*          The leading dimension of the array AF.  LDAF >= max(1,N).
-*
-*  IPIV    (input) INTEGER array, dimension (N)
-*          The pivot indices from DGETRF; for 1<=i<=N, row i of the
-*          matrix was interchanged with row IPIV(i).
-*
-*  B       (input) DOUBLE PRECISION array, dimension (LDB,NRHS)
-*          The right hand side matrix B.
-*
-*  LDB     (input) INTEGER
-*          The leading dimension of the array B.  LDB >= max(1,N).
-*
-*  X       (input/output) DOUBLE PRECISION array, dimension (LDX,NRHS)
-*          On entry, the solution matrix X, as computed by DGETRS.
-*          On exit, the improved solution matrix X.
-*
-*  LDX     (input) INTEGER
-*          The leading dimension of the array X.  LDX >= max(1,N).
-*
-*  FERR    (output) DOUBLE PRECISION array, dimension (NRHS)
-*          The estimated forward error bound for each solution vector
-*          X(j) (the j-th column of the solution matrix X).
-*          If XTRUE is the true solution corresponding to X(j), FERR(j)
-*          is an estimated upper bound for the magnitude of the largest
-*          element in (X(j) - XTRUE) divided by the magnitude of the
-*          largest element in X(j).  The estimate is as reliable as
-*          the estimate for RCOND, and is almost always a slight
-*          overestimate of the true error.
-*
-*  BERR    (output) DOUBLE PRECISION array, dimension (NRHS)
-*          The componentwise relative backward error of each solution
-*          vector X(j) (i.e., the smallest relative change in
-*          any element of A or B that makes X(j) an exact solution).
-*
-*  WORK    (workspace) DOUBLE PRECISION array, dimension (3*N)
-*
-*  IWORK   (workspace) INTEGER array, dimension (N)
-*
-*  INFO    (output) INTEGER
-*          = 0:  successful exit
-*          < 0:  if INFO = -i, the i-th argument had an illegal value
-*
-*  Internal Parameters
-*  ===================
-*
-*  ITMAX is the maximum number of steps of iterative refinement.
-*
-*  =====================================================================
-*
-*     .. Parameters ..
-      INTEGER            ITMAX
-      PARAMETER          ( ITMAX = 5 )
-      DOUBLE PRECISION   ZERO
-      PARAMETER          ( ZERO = 0.0D+0 )
-      DOUBLE PRECISION   ONE
-      PARAMETER          ( ONE = 1.0D+0 )
-      DOUBLE PRECISION   TWO
-      PARAMETER          ( TWO = 2.0D+0 )
-      DOUBLE PRECISION   THREE
-      PARAMETER          ( THREE = 3.0D+0 )
-*     ..
-*     .. Local Scalars ..
-      LOGICAL            NOTRAN
-      CHARACTER          TRANST
-      INTEGER            COUNT, I, J, K, KASE, NZ
-      DOUBLE PRECISION   EPS, LSTRES, S, SAFE1, SAFE2, SAFMIN, XK
-*     ..
-*     .. Local Arrays ..
-      INTEGER            ISAVE( 3 )
-*     ..
-*     .. External Subroutines ..
-      EXTERNAL           DAXPY, DCOPY, DGEMV, DGETRS, DLACN2, XERBLA
-*     ..
-*     .. Intrinsic Functions ..
-      INTRINSIC          ABS, MAX
-*     ..
-*     .. External Functions ..
-      LOGICAL            LSAME
-      DOUBLE PRECISION   DLAMCH
-      EXTERNAL           LSAME, DLAMCH
-*     ..
-*     .. Executable Statements ..
-*
-*     Test the input parameters.
-*
-      INFO = 0
-      NOTRAN = LSAME( TRANS, 'N' )
-      IF( .NOT.NOTRAN .AND. .NOT.LSAME( TRANS, 'T' ) .AND. .NOT.
-     $    LSAME( TRANS, 'C' ) ) THEN
-         INFO = -1
-      ELSE IF( N.LT.0 ) THEN
-         INFO = -2
-      ELSE IF( NRHS.LT.0 ) THEN
-         INFO = -3
-      ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
-         INFO = -5
-      ELSE IF( LDAF.LT.MAX( 1, N ) ) THEN
-         INFO = -7
-      ELSE IF( LDB.LT.MAX( 1, N ) ) THEN
-         INFO = -10
-      ELSE IF( LDX.LT.MAX( 1, N ) ) THEN
-         INFO = -12
-      END IF
-      IF( INFO.NE.0 ) THEN
-         CALL XERBLA( 'DGERFS', -INFO )
-         RETURN
-      END IF
-*
-*     Quick return if possible
-*
-      IF( N.EQ.0 .OR. NRHS.EQ.0 ) THEN
-         DO 10 J = 1, NRHS
-            FERR( J ) = ZERO
-            BERR( J ) = ZERO
-   10    CONTINUE
-         RETURN
-      END IF
-*
-      IF( NOTRAN ) THEN
-         TRANST = 'T'
-      ELSE
-         TRANST = 'N'
-      END IF
-*
-*     NZ = maximum number of nonzero elements in each row of A, plus 1
-*
-      NZ = N + 1
-      EPS = DLAMCH( 'Epsilon' )
-      SAFMIN = DLAMCH( 'Safe minimum' )
-      SAFE1 = NZ*SAFMIN
-      SAFE2 = SAFE1 / EPS
-*
-*     Do for each right hand side
-*
-      DO 140 J = 1, NRHS
-*
-         COUNT = 1
-         LSTRES = THREE
-   20    CONTINUE
-*
-*        Loop until stopping criterion is satisfied.
-*
-*        Compute residual R = B - op(A) * X,
-*        where op(A) = A, A**T, or A**H, depending on TRANS.
-*
-         CALL DCOPY( N, B( 1, J ), 1, WORK( N+1 ), 1 )
-         CALL DGEMV( TRANS, N, N, -ONE, A, LDA, X( 1, J ), 1, ONE,
-     $               WORK( N+1 ), 1 )
-*
-*        Compute componentwise relative backward error from formula
-*
-*        max(i) ( abs(R(i)) / ( abs(op(A))*abs(X) + abs(B) )(i) )
-*
-*        where abs(Z) is the componentwise absolute value of the matrix
-*        or vector Z.  If the i-th component of the denominator is less
-*        than SAFE2, then SAFE1 is added to the i-th components of the
-*        numerator and denominator before dividing.
-*
-         DO 30 I = 1, N
-            WORK( I ) = ABS( B( I, J ) )
-   30    CONTINUE
-*
-*        Compute abs(op(A))*abs(X) + abs(B).
-*
-         IF( NOTRAN ) THEN
-            DO 50 K = 1, N
-               XK = ABS( X( K, J ) )
-               DO 40 I = 1, N
-                  WORK( I ) = WORK( I ) + ABS( A( I, K ) )*XK
-   40          CONTINUE
-   50       CONTINUE
-         ELSE
-            DO 70 K = 1, N
-               S = ZERO
-               DO 60 I = 1, N
-                  S = S + ABS( A( I, K ) )*ABS( X( I, J ) )
-   60          CONTINUE
-               WORK( K ) = WORK( K ) + S
-   70       CONTINUE
-         END IF
-         S = ZERO
-         DO 80 I = 1, N
-            IF( WORK( I ).GT.SAFE2 ) THEN
-               S = MAX( S, ABS( WORK( N+I ) ) / WORK( I ) )
-            ELSE
-               S = MAX( S, ( ABS( WORK( N+I ) )+SAFE1 ) /
-     $             ( WORK( I )+SAFE1 ) )
-            END IF
-   80    CONTINUE
-         BERR( J ) = S
-*
-*        Test stopping criterion. Continue iterating if
-*           1) The residual BERR(J) is larger than machine epsilon, and
-*           2) BERR(J) decreased by at least a factor of 2 during the
-*              last iteration, and
-*           3) At most ITMAX iterations tried.
-*
-         IF( BERR( J ).GT.EPS .AND. TWO*BERR( J ).LE.LSTRES .AND.
-     $       COUNT.LE.ITMAX ) THEN
-*
-*           Update solution and try again.
-*
-            CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
-     $                   INFO )
-            CALL DAXPY( N, ONE, WORK( N+1 ), 1, X( 1, J ), 1 )
-            LSTRES = BERR( J )
-            COUNT = COUNT + 1
-            GO TO 20
-         END IF
-*
-*        Bound error from formula
-*
-*        norm(X - XTRUE) / norm(X) .le. FERR =
-*        norm( abs(inv(op(A)))*
-*           ( abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) ))) / norm(X)
-*
-*        where
-*          norm(Z) is the magnitude of the largest component of Z
-*          inv(op(A)) is the inverse of op(A)
-*          abs(Z) is the componentwise absolute value of the matrix or
-*             vector Z
-*          NZ is the maximum number of nonzeros in any row of A, plus 1
-*          EPS is machine epsilon
-*
-*        The i-th component of abs(R)+NZ*EPS*(abs(op(A))*abs(X)+abs(B))
-*        is incremented by SAFE1 if the i-th component of
-*        abs(op(A))*abs(X) + abs(B) is less than SAFE2.
-*
-*        Use DLACN2 to estimate the infinity-norm of the matrix
-*           inv(op(A)) * diag(W),
-*        where W = abs(R) + NZ*EPS*( abs(op(A))*abs(X)+abs(B) )))
-*
-         DO 90 I = 1, N
-            IF( WORK( I ).GT.SAFE2 ) THEN
-               WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I )
-            ELSE
-               WORK( I ) = ABS( WORK( N+I ) ) + NZ*EPS*WORK( I ) + SAFE1
-            END IF
-   90    CONTINUE
-*
-         KASE = 0
-  100    CONTINUE
-         CALL DLACN2( N, WORK( 2*N+1 ), WORK( N+1 ), IWORK, FERR( J ),
-     $                KASE, ISAVE )
-         IF( KASE.NE.0 ) THEN
-            IF( KASE.EQ.1 ) THEN
-*
-*              Multiply by diag(W)*inv(op(A)**T).
-*
-               CALL DGETRS( TRANST, N, 1, AF, LDAF, IPIV, WORK( N+1 ),
-     $                      N, INFO )
-               DO 110 I = 1, N
-                  WORK( N+I ) = WORK( I )*WORK( N+I )
-  110          CONTINUE
-            ELSE
-*
-*              Multiply by inv(op(A))*diag(W).
-*
-               DO 120 I = 1, N
-                  WORK( N+I ) = WORK( I )*WORK( N+I )
-  120          CONTINUE
-               CALL DGETRS( TRANS, N, 1, AF, LDAF, IPIV, WORK( N+1 ), N,
-     $                      INFO )
-            END IF
-            GO TO 100
-         END IF
-*
-*        Normalize error.
-*
-         LSTRES = ZERO
-         DO 130 I = 1, N
-            LSTRES = MAX( LSTRES, ABS( X( I, J ) ) )
-  130    CONTINUE
-         IF( LSTRES.NE.ZERO )
-     $      FERR( J ) = FERR( J ) / LSTRES
-*
-  140 CONTINUE
-*
-      RETURN
-*
-*     End of DGERFS
-*
-      END