upgrade ngspice to v31

10 files changed, 681 insertions, 0 deletions

diff --git a/Windows/spice/examples/vbic/DFF_Y_ECL.sp b/Windows/spice/examples/vbic/DFF_Y_ECL.sp
new file mode 100644
index 00000000..5afeb8f1
--- /dev/null
+++ b/Windows/spice/examples/vbic/DFF_Y_ECL.sp
@@ -0,0 +1,55 @@
+ECL DFF VBIC test case
+*
+V6 D GND PULSE(-.25 0 0 1P 1P .25N .50N)   
+V5 D_BAR GND PULSE(0 -.25 0 1P 1P .25N .50N)   
+V4 CLK GND PULSE(-0.9 -1.2 0 1P 1P .125N .25N)   
+V3 CLK_BAR GND PULSE(-1.2 -0.9 0 1P 1P .125N .25N)   
+VVCS NET2 GND DC -0.8 
+R6 GND NET6  800 
+R5 GND NET11  800 
+R4 NET12 VEE  350 
+VVEE VEE GND DC -2.0 
+R3 GND NET10  800 
+R2 NET13 VEE  350 
+R1 GND Q  800 
+QVLGNPN16 NET7 CLK_BAR NET4 VEE NPN_VBIC_VLG
+QVLGNPN15 NET5 CLK NET3 VEE NPN_VBIC_VLG
+QVLGNPN14 NET10 Q NET7 VEE NPN_VBIC_VLG
+QVLGNPN13 Q NET6 NET9 VEE NPN_VBIC_VLG
+QVLGNPN12 NET6 NET11 NET5 VEE NPN_VBIC_VLG
+QVLGNPN11 NET11 D_BAR NET8 VEE NPN_VBIC_VLG
+QVLGNPN10 NET4 NET2 NET13 VEE NPN_VBIC_VLG
+QVLGNPN9 NET3 NET2 NET12 VEE NPN_VBIC_VLG
+QVLGNPN8 NET8 CLK_BAR NET3 VEE NPN_VBIC_VLG
+QVLGNPN7 NET9 CLK NET4 VEE NPN_VBIC_VLG
+QVLGNPN6 Q NET10 NET7 VEE NPN_VBIC_VLG
+QVLGNPN5 NET10 NET11 NET9 VEE NPN_VBIC_VLG
+QVLGNPN4 NET11 NET6 NET5 VEE NPN_VBIC_VLG
+QVLGNPN3 NET6 D NET8 VEE NPN_VBIC_VLG
+*
+.MODEL NPN_VBIC_VLG NPN LEVEL=4
++TNOM    = 27             RCI     = 1E3            RCX     = 50                 
++VO      = 1.5            GAMM    = 3.402097E-11   HRCF    = 1                  
++RBX     = 243            RBI     = 20             RE      = 30                 
++RS      = 0              RBP     = 0              IS      = 8.084033E-18       
++NF      = 1              NR      = 1.005          FC      = 0.5                
++CJE     = 2.083234E-15   PE      = 0.8793669      ME      = 0.3108762          
++CJC     = 1.803275E-15   PC      = 0.5512188      MC      = 0.4454263          
++CJCP    = 8E-15          PS      = 0.66956        MS      = 0.2243             
++IBEI    = 4.542609E-20   WBE     = 1              NEI     = 1                  
++IBEN    = 3.275162E-16   NEN     = 1.5543186      IBCI    = 3.594252E-19       
++NCI     = 0.996          IBCN    = 1.717776E-17   NCN     = 1.202521           
++AVC1    = 3E-4           AVC2    = 1E-5           ISP     = 1.332E-19          
++WSP     = 1              NFP     = 1              IBEIP   = 0                  
++IBENP   = 0              IBCIP   = 0              NCIP    = 1                  
++IBCNP   = 0              NCNP    = 2              VEF     = 109.6523           
++VER     = 2.2052435      IKF     = 6.03524E-3     IKR     = 1.807895E-4        
++IKP     = 2.908576E-5    TF      = 1.1E-12        XTF     = 21.5423            
++VTF     = 12.4758677     ITF     = 0.0175231      TR      = 2.23542E-9       
+
+.SAVE V(D) V(CLK) V(Q)
+.control
+TRAN 0.25p 10n
+plot V(D) V(CLK) V(Q)
+.endc
+.END
diff --git a/Windows/spice/examples/vbic/Infineon_VBIC.lib b/Windows/spice/examples/vbic/Infineon_VBIC.lib
new file mode 100644
index 00000000..29018daa
--- /dev/null
+++ b/Windows/spice/examples/vbic/Infineon_VBIC.lib
@@ -0,0 +1,287 @@
+***************************************************************
+* Comments for the user:
+* The VBIC Model includes the self heating effect and the user can switch selfheating on or off.
+* a) no self heating: set Rth = 0
+* b) with self heating: set Rth=80K/W + Rth_PCB (customer)
+* Note: Rth = 80 K/W includes only the thermal resistance of die and package and
+* the thermal resistance of the customer PCB must be added (Rth=80K/W + Rth_PCB)
+
+*   Infineon    Technologies    AG
+*   VBIC    MODEL   IN  SPICE   2G6 SYNTAX
+*   VALID   UP  TO  10  GHZ
+*   >>> BFP780  <<<
+*   (C) 2015    Infineon    Technologies    AG
+*   Version 1.1 October 2015
+***************************************************************
+*.OPTION TNOM=25, GMIN= 1.00e-12
+*BFP780 C B E1 E2
+.SUBCKT BFP780 1 2 3 4
+*
+CCEPAR 11 33  800E-015
+*
+LEx    30 35 3E-011
+LBx    20 2  3E-011
+LCx    10 1  3E-011
+*
+CBPAD 22 44  30E-015
+CCPAD 11 44  30E-015
+CEPAD 33 44  30E-015
+*
+LB   22 20 777E-12
+LC   10 11 777E-12
+*
+CBEPCK 20 30  5.703E-015
+CBCPCK 10 20  1.497E-014
+CCEPCK 10 30  6.032E-014
+*
+RE1 35 3 1E-03
+RE2 35 4 1E-03
+*
+Rsub1 44 30 0.2144
+Rps 44 33 0.07306
+*
+D1 33 22 Diode_fb
+D2 44 22 Diode_fbd
+*
+.MODEL Diode_fb D(
++ IS=3.5E-015
++ N=1
++ CJO=10e-15
++ RS=6.1
++ Tnom=25)
+*
+.MODEL Diode_fbd D(
++ IS=1E-015
++ N=1
++ CJO=10E-15
++ RS=1
++ Tnom=25)
+*
+Q1 11 22 33 44 M_BFP780
+*
+.ENDS BFP780
+.MODEL  M_BFP780    NPN (Level=4
++ Tnom=25
++ Cbeo=2.47E-012
++ Cje=561.3E-015
++ Pe=0.7
++ Me=0.333
++ Aje=-1
++ Wbe=1
++ Cbco=10E-015
++ Cjc=668.6E-015
++ Pc=0.54
++ Mc=0.333
++ Ajc=-1
++ Cjep=2.616E-015
++ Cjcp=900E-015
++ Ps=0.6
++ Ms=0.3
++ Ajs=-0.5
++ Fc=0.94
++ Vef=545.4
++ Ver=3.291
++ Is=2.3E-015
++ Nf=0.9855
++ Ibei=1.893E-018
++ Nei=0.9399
++ Iben=4.77E-015
++ Nen=1.361
++ Ikf=1
++ Nr=0.9912
++ Ibci=157.5E-018
++ Nci=1.1
++ Ibcn=4.929E-015
++ Ncn=1.463
++ Ikr=0.01178
++ Wsp=1
++ Isp=1E-015
++ Nfp=1
++ Ibcip=1E-015
++ Ncip=1.029
++ Ibcnp=1E-015
++ Ncnp=1
++ Ikp=1E-3
++ Ibeip=1E-015
++ Ibenp=1E-015
++ Re=0.15
++ Rcx=0.01
++ Rci=2.665
++ Qco=1E-015
++ Vo=0.0005022
++ Gamm=5.659E-012
++ Hrcf=0.21
++ Rbx=5
++ Rbi=1.964
++ Rbp=265.5
++ Rs=26.56
++ Avc1=3.97
++ Avc2=29.52
++ Tf=1.6E-012
++ Qtf=50E-3
++ Xtf=30
++ Vtf=0.7
++ Itf=1
++ Tr=1E-015
++ Td=500E-015
++ Cth=0
++ Rth=80
++ Ea=1.12
++ Eaie=1.12
++ Eaic=1.12
++ Eais=1
++ Eane=1.12
++ Eanc=1.12
++ Eans=1
++ Xre=0
++ Xrb=0
++ Xrc=0
++ Xrs=0
++ Xvo=0
++ Xis=-1.631
++ Xii=0
++ Xin=0
++ Tnf=0
++ Tavc=0.002613
++ Kfn=0
++ Afn=1
++ Bfn=1 )
+***************************************************************
+*
+*.ENDS BFP780
+***************************************************************
+* Comments for the user:
+* The VBIC Model includes the self heating effect and the user can switch selfheating on or off.
+* a) no self heating: set Rth = 0
+* b) with self heating: set Rth=20K/W + Rth_PCB (customer)
+* Note: Rth = 20 K/W includes only the thermal resistance of die and package and
+* the thermal resistance of the customer PCB must be added (Rth=20K/W + Rth_PCB)
+
+*   Infineon    Technologies    AG
+*   VBIC    MODEL
+*   VALID   UP  TO  6   GHZ
+*   >>> BFQ790  <<<
+*   (C) 2015    Infineon    Technologies    AG
+*   Version 1.0 Juni    2015
+***************************************************************
+*.OPTION TNOM=25, GMIN= 1.00e-12
+*BFQ790 C B E
+
+* without access to the external thermal node (Rth to be adjusted by the customer in the model parameter list for the transistor
+.SUBCKT BFQ790 1 2 3
+*
+* with access to external thermal node
+*.SUBCKT BFQ790 1 2 3 55
+*
+CCSPAR 11 44 1.375E-012
+LEx    30 3 4.36882E-011
+LBx    20 2 2.77681E-011
+LCx    10 1 4.265E-011
+CBEPCK 20 30  1.105E-013
+CBCPCK 10 20  1E-014
+CCEPCK 10 30  1E-015
+LB   222 20 1.02449E-009
+LC   10 11  1.89901E-009
+*
+RBL 222 22 45
+CBL 222 22  3E-011
+*
+Rsub1 44 30 0.000500184
+Rps 44 33 0.102733
+*
+*
+* without access to the external thermal node
+Q1 11 22 33 44 M_BFQ790
+*
+* with access to the thermal node
+* Q1 11 22 33 44 55 M_BFQ790
+*
+.MODEL  M_BFQ790 NPN Level=4(
++ Tnom=25
++ Cbeo=9.31E-012
++ Cje=7.693E-013
++ Pe=0.5892
++ Me=0.3115
++ Aje=-0.5
++ Wbe=1
++ Cbco=1.966E-013
++ Cjc=1E-015
++ Pc=0.5095
++ Mc=0.2797
++ Ajc=-0.5
++ Cjep=1.875E-012
++ Cjcp=2.067E-012
++ Ps=0.5086
++ Ms=0.2865
++ Ajs=-0.5
++ Fc=0.93
++ Vef=615.1
++ Ver=5.61838
++ Is=9.704E-015
++ Nf=1.001
++ Ibei=5E-017
++ Nei=1.013
++ Iben=3.609E-014
++ Nen=1.46
++ Ikf=2
++ Nr=0.9958
++ Ibci=1.001E-017
++ Nci=1.015
++ Ibcn=2.918E-014
++ Ncn=1.399
++ Ikr=0.2301
++ Wsp=1
++ Isp=1E-015
++ Nfp=1
++ Ibcip=2E-017
++ Ncip=1
++ Ibcnp=1.7E-015
++ Ncnp=1.67
++ Ikp=0.0002
++ Ibeip=7E-017
++ Ibenp=2.4E-014
++ Re=0.2
++ Rcx=0.02559
++ Rci=1.168
++ Qco=4E-015
++ Vo=0.4234
++ Gamm=2.199E-012
++ Hrcf=0.1907
++ Rbx=0.2825
++ Rbi=1.868
++ Rbp=0.001
++ Rs=10
++ Avc1=1
++ Avc2=25.84
++ Tf=3E-012
++ Qtf=0.6758
++ Xtf=0.01293
++ Vtf=0.5
++ Itf=0.1948
++ Tr=1E-015
++ Td=1E-015
++ Cth=0
++ Rth=20.05
++ Ea=1.12
++ Eaie=1.12
++ Eaic=1.12
++ Eais=1.12
++ Eane=1.12
++ Eanc=1.12
++ Eans=1.12
++ Xre=0
++ Xrb=0
++ Xrc=0
++ Xrs=0
++ Xvo=0
++ Xis=1.907
++ Xii=4.963
++ Xin=-2.837
++ Tnf=1E-006
++ Tavc=0.006705
++ Kfn=0
++ Afn=1
++ Bfn=1 )
+***************************************************************
+*
+.ENDS BFQ790
diff --git a/Windows/spice/examples/vbic/npn_ft.sp b/Windows/spice/examples/vbic/npn_ft.sp
new file mode 100644
index 00000000..90854519
--- /dev/null
+++ b/Windows/spice/examples/vbic/npn_ft.sp
@@ -0,0 +1,41 @@
+VBIC ft Test
+
+.include Infineon_VBIC.lib
+
+vce 1 0 dc 3.0
+vgain 1 c dc 0.0
+f 0 2 vgain -1000
+l 2 b 1g
+c 2 0 1g
+ib 0 b dc 0.0 ac 1.0
+ic 0 c 0.01
+xq1 c b 0 0 BFP780
+
+.control
+let ft_runs = 13
+let run = 0
+set curplot=new          $ create a new plot
+set curplotname=ft_plot
+set curplottitle="Infineon BFP780 ft = f(Ic)"
+set scratch=$curplot     $ store its name to 'scratch'
+setplot $scratch         $ make 'scratch' the active plot 
+let ft=unitvec(ft_runs)  $ create a vector in plot 'scratch' to store ft data 
+let ic=unitvec(ft_runs)  $ create a vector in plot 'scratch' to store ic data 
+foreach myic 1m 4m 7m 10m 20m 40m 60m 75m 90m 100m 110m 130m 180m
+ alter ic = $myic
+ ac dec 100 100k 50g
+*plot vdb(vgain#branch)
+ meas ac freq_at when vdb(vgain#branch)=0
+ set run ="$&run"            $ create a variable from the vector
+ set dt = $curplot           $ store the current plot to dt
+ setplot $scratch            $ make 'scratch' the active plot
+ let ic[run] = $myic         $ store ic to vector ft in plot 'scratch'
+ let ft[run] = {$dt}.freq_at $ store ft to vector ft in plot 'scratch'
+ setplot $dt                 $ go back to the previous plot
+ let run = run + 1
+end
+setplot unknown1
+plot ft vs ic xlog
+.endc
+
+.end
diff --git a/Windows/spice/examples/vbic/npn_gum.sp b/Windows/spice/examples/vbic/npn_gum.sp
new file mode 100644
index 00000000..76d0a93a
--- /dev/null
+++ b/Windows/spice/examples/vbic/npn_gum.sp
@@ -0,0 +1,17 @@
+VBIC Gummel Test Ic=f(Vc,Vb)
+
+.include qnva.mod
+
+VB B 0 0.5
+VC C 0 1.0
+VS S 0 0.0
+XQ1 C B 0 S qnva
+
+.control
+options gmin=1e-15
+dc vb 0.2 1.2 0.01
+plot abs(i(vc)) abs(i(vb)) abs(i(vs)) ylimit 0.1e-12 100e-3 ylog
+plot abs(i(vc))/abs(i(vb)) vs abs(-i(vc)) xlog xlimit 10e-12 10e-3 ylimit 0 40
+.endc
+
+.end
diff --git a/Windows/spice/examples/vbic/npn_out.sp b/Windows/spice/examples/vbic/npn_out.sp
new file mode 100644
index 00000000..30256ec4
--- /dev/null
+++ b/Windows/spice/examples/vbic/npn_out.sp
@@ -0,0 +1,16 @@
+VBIC Output Test Ic=f(Vc,Ib)
+
+.include qnva.mod
+
+IB 0 B 200n
+VC C 0 2.0
+VS S 0 0.0
+XQ1 C B 0 S qnva
+
+.control
+dc vc 0.0 5.0 0.05 ib 1u 10u 1u
+run
+plot abs(i(vc))
+.endc
+
+.end
diff --git a/Windows/spice/examples/vbic/qnva.mod b/Windows/spice/examples/vbic/qnva.mod
new file mode 100644
index 00000000..150e74c5
--- /dev/null
+++ b/Windows/spice/examples/vbic/qnva.mod
@@ -0,0 +1,94 @@
+.param
++qnva_is=1.000e+00
++qnva_re=1.000e+00
++qnva_cje=1.000e+00
++qnva_cjc=1.000e+00
++qnva_vef=1.000e+00
++qnva_rcx=1.000e+00
++qnva_rbx=1.000e+00
++qnva_rci=1.000e+00
++qnva_ibei=1.000e+00
++qnva_iben=0.000e+00
++qnva_cjep=1.000e+00
++qnva_cjcp=1.000e+00
++qnva_ais=0.000e+00
++qnva_aibei=0.000e+00
++qnva_aiben=0.000e+00
+
+.subckt qnva c b e s le=2.02 par1=1
+q1 c b e s qnvamod area=1
+.model qnvamod npn level=9
++ tref=2.700e+01
++ ebbe=2.111e-05
++ vo=0.000e+00
++ gamm=1.493e-13               hrcf=0.000e+00
++ nf=1.000e+00                 nr=1.008e+00
++ fc=8.300e-01                 pe=6.500e-01
++ me=3.500e-01                 aje=-5.000e-01
++ qco=0.000e+00                pc=6.500e-01
++ mc=3.200e-01                 ajc=-5.000e-01
++ ps=6.000e-01                 ms=3.700e-01
++ ajs=-5.000e-01               wbe=4.800e-01
++ nei=1.000e+00                nen=2.000e+00
++ nci=1.000e+00                ncn=2.100e+00
++ avc1=2.258e+00
++ wsp=1.000e+00                nfp=1.000e+00
++ ncip=1.000e+00               ncnp=2.000e+00
++ ver=8.807e+00                qtf=0.000e+00
++ xtf=3.770e+00                vtf=1.667e+00
++ tr=3.500e-10                 td=0.000e+00
++ afn=1.000e+00                kfn=5.500e-14
++ bfn=1.000e+00
++ xrbi=0.000e+00               xrci=0.000e+00
++ xre=0.000e+00                xrs=0.000e+00
++ xvo=0.000e+00                ea=1.130e+00
++ eaie=1.130e+00               eaic=1.110e+00
++ eais=1.110e+00               eane=1.110e+00
++ eanc=1.110e+00               eans=1.110e+00
++ xis=4.864e+00                xii=2.952e+00
++ xin=2.952e+00
++ tnf=0.000e+00                tavc=6.580e-04
++ rth='(0.000e+00/le+0.000e+00)'
++ cth='(0.000e+00*le+0.000e+00)'
++ vrt=0.000e+00                art=1.000e-01
++ qbm=1.000e+00                nkf=5.000e-01
++ xikf=1.000e+00               xrcx=0.000e+00
++ xrbx=0.000e+00               xrbp=0.000e+00
++ isrr=1.230e+00               xisr=0.000e+00
++ dear=0.000e+00               eap=1.110e+00
++ vbbe=2.266e+00               nbbe=6.584e+00
++ tvbbe1=2.000e-04             tvbbe2=0.000e+00
++ tnbbe=-1.900e-03
++ vef='qnva_vef*1.500e+01'
++ tf='1.000e+00*4.300e-12'
++ rcx='qnva_rcx*(1/(le/3.800e+02+1/3.000e+02))'
++ rci='qnva_rci*(1/(le/7.200e+02+1/4.800e+02))'
++ rbx='qnva_rbx*(1/(le/2.000e+02+1/1.000e+04))'
++ rbi='1.000e+00*(1/(le/3.000e+01+1/1.000e+04))'
++ rbp='1/(le/3.000e+01+1/1.000e+04)'
++ re='qnva_re*(1.800e+01/le+(2.778e+00))'
++ rs='1/(le/1.500e+01+1/1.000e+04)'
++ is='(1+qnva_ais/sqrt(par1*le))*qnva_is*(le*1.181e-18+(3.202e-19))'
++ cbeo='(le*0.000e+00+(5.000e-15))'
++ cbco='(le*0.000e+00+(3.000e-15))'
++ cje='qnva_cje*(le*2.326e-15+(-4.733e-30))'
++ cjc='qnva_cjc*(le*1.196e-15+(2.381e-15))'
++ cjep='qnva_cjep*(le*1.196e-15+(2.381e-15))'
++ cjcp='qnva_cjcp*(le*1.824e-15+(1.814e-14))'
++ ibei='(1+qnva_aibei/sqrt(par1*le))*qnva_ibei*(le*4.032e-20+(3.890e-21))'
++ iben='exp((qnva_aiben/sqrt(par1*le))+(qnva_iben))*(le*4.125e-16+(-6.420e-20))'
++ ibci='(le*1.220e-20+(1.086e-23))'
++ ibcn='(le*1.636e-15+(1.557e-18))'
++ isp='(le*1.137e-18+(2.280e-18))'
++ ibeip='(le*6.558e-20+(2.802e-19))'
++ ibenp='(le*3.311e-20+(-5.172e-24))'
++ ibcip='(le*4.290e-17+(7.958e-16))'
++ ibcnp='(le*6.212e-16+(-1.632e-19))'
++ ikf='1.000e+00*(le*1.253e-03+(2.165e-07))'
++ ikr='(le*1.540e-04+(-1.077e-07))'
++ ikp='(le*4.007e-05+(4.615e-05))'
++ itf='(le*5.037e-03+(-2.423e-06))'
++ ccso='(le*0.000e+00+(1.000e-18))'
++ ibbe='(le*7.769e-09+(-1.684e-12))'
++ avc2='1/(1.590e-03/le+1/1.892e+01)'
+.ends qnva
diff --git a/Windows/spice/examples/vbic/self-heat.sp b/Windows/spice/examples/vbic/self-heat.sp
new file mode 100644
index 00000000..02a9695d
--- /dev/null
+++ b/Windows/spice/examples/vbic/self-heat.sp
@@ -0,0 +1,51 @@
+VBIC Output Test Ic=f(Vc,Ib) vs self heating
+.option absmos=1e-12 relmos=1e-6 relv=1e-6 absv=1e-9 post
+vc c 0 0
+vb b 0 1
+ve e 0 0
+vs s 0 0
+vc1 c c1 0
+vb1 b b1 0
+ve1 e e1 0
+vs1 s s1 0
+.temp 27
+Q1 c1 b1 e1 s1 t mod1 area=1
+.model mod1 npn Level=4
++ Tnom=27 RCX=10 RCI=60 VO=2 GAMM=2.e-11
++ HRCF=2 RBX=10 RBI=40 RE=2
++ RS=20 RBP=40 IS=1e-16 NF=1.00000e+00
++ NR=1.00000e+00 FC=9.00000e-01 CBEO=0
++ CJE=1.e-13 PE=0.75 ME=0.33
++ AJE=-5.00000e-01 CBCO=0 CJC=2e-14
++ QCO=1e-12 CJEP=1e-13 PC=7.50000e-01
++ MC=3.30000e-01 AJC=-5.00000e-01 CJCP=4e-13
++ PS=7.50000e-01 MS=3.30000e-01 AJS=-5.00000e-01
++ IBEI=1e-18 WBE=1.0000 NEI=1.00000e+00
++ IBEN=5e-15 NEN=2.00000e+00 IBCI=2e-17
++ NCI=1.00000e+00 IBCN=5e-15 NCN=2.00000e+00
++ AVC1=2 AVC2=15 ISP=1e-15
++ WSP=1.000e+00 NFP=1.00000e+00 IBEIP=0
++ IBENP=0 IBCIP=0 NCIP=1.00000e+00
++ IBCNP=0 NCNP=2.00000e+00 VEF=10
++ VER=4 IKF=0.002 IKR=0.0002 IKP=0.0002
++ TF=1.e-11 QTF=0 XTF=20
++ VTF=0 ITF=0.08 TR=1e-10
++ KFN=0 AFN=1.0e+00
++ BFN=1.0000e+00 XRE=0 XRB=0
++ XRC=0 XRS=0 XVO=0
++ EA=1.12000e+00 EAIE=1.12000e+00
++ EANE=1.12000e+00 EANC=1.12000e+00
++ EANS=1.12000e+00 XIS=3.00000e+00
++ XII=3.00000e+00 XIN=3.00000e+00
++ TNF=0 TAVC=0
++ RTH=300 CTH=0
++ TD=0
+*+ TD=2.e-11
+.control
+dc vc 0.0 5.0001 0.05 vb 0.7 1.0001 0.05
+altermod @mod1[RTH]=0
+dc vc 0.0 5.0001 0.05 vb 0.7 1.0001 0.05
+plot dc1.vc1#branch dc2.vc1#branch
+.endc
+.end
+
diff --git a/Windows/spice/examples/vbic/vbic99_dc.sp b/Windows/spice/examples/vbic/vbic99_dc.sp
new file mode 100644
index 00000000..f2e91ac0
--- /dev/null
+++ b/Windows/spice/examples/vbic/vbic99_dc.sp
@@ -0,0 +1,46 @@
+***** VBIC99 level9 DC test *****
+.OPTION gmin=1.0e-15
+vbe bx 0 0
+vcb cx bx 0
+vib bx b 0
+vic cx c 0
+ve ex 0 0
+vie ex e 0
+vs sx 0 0
+vis sx s 0
+q1 c b e s dt vbic99 area=1 m=1
+.model vbic99 npn level=9
++tref = 27.0 rcx = 10.0 rci = 60.0 vo = 2.0
++gamm = 2e-11 hrcf = 2.0 rbx = 10.0 rbi = 40.0
++re = 2.0 rs = 20.0 rbp = 40.0 is = 1.0e-16
++nf = 1.0 nr = 1.0 fc = 0.9 cbeo = 0.0
++cje = 1.0e-13 pe = 0.75 me = 0.33 aje = -0.5
++cbco = 0.0 cjc = 2e-14 qco = 1e-12 cjep = 1e-13
++pc = 0.75 mc = 0.33 ajc = -0.5 cjcp = 4e-13
++ps = 0.75 ms = 0.33 ajs = -0.5 ibei = 1.0e-18
++wbe = 1.0 nei = 1.0 iben = 5.0e-15 nen = 2.0
++ibci = 2.0e-17 nci = 1.0 ibcn = 5.0e-15 ncn = 2.0
++avc1 = 2.0 avc2 = 15.0 isp = 1.0e-15 wsp = 1.0
++nfp = 1.0 ibeip = 0.0 ibenp = 0.0 ibcip = 0.0
++ncip = 1.0 ibcnp = 0.0 ncnp = 2.0 vef = 10.0
++ver = 4.0 ikf = 2e-3 ikr = 2e-4 ikp = 2e-4
++tf = 10e-12 qtf = 0.0 xtf = 20.0 vtf = 0.0
++itf = 8e-2 tr = 100e-12 td = 1e-20 kfn = 0.0
++afn = 1.0 bfn = 1.0 xre = 0 xrbi = 0
++xrci = 0 xrs = 0 xvo = 0 ea = 1.12
++eaie = 1.12 eaic = 1.12 eais = 1.12 eane = 1.12
++eanc = 1.12 eans = 1.12 xis = 3.0 xii = 3.0
++xin = 3.0 tnf = 0.0 tavc = 0.0 rth = 300.0
++cth = 0.0 vrt = 0.0 art = 0.1 ccso = 0.0
++qbm = 0.0 nkf = 0.5 xikf = 0 xrcx = 0
++xrbx = 0 xrbp = 0 isrr = 1.0 xisr = 0.0
++dear = 0.0 eap = 1.12 vbbe = 0.0 nbbe = 1.0
++ibbe = 1.0e-6 tvbbe1 = 0.0 tvbbe2 = 0.0 tnbbe = 0.0
++ebbe = 0.0
+.temp 27
+.control
+dc vbe 0.1 1.1 0.02
+plot i(vib) i(vic) abs(i(vis)) ylog
+plot v(dt)
+.endc
+.end
diff --git a/Windows/spice/examples/vbic/vbic99_tran.sp b/Windows/spice/examples/vbic/vbic99_tran.sp
new file mode 100644
index 00000000..d86c1616
--- /dev/null
+++ b/Windows/spice/examples/vbic/vbic99_tran.sp
@@ -0,0 +1,54 @@
+***** VBIC99 level 9 Transient test *****
+*
+q1 3 2 0 0 t vbic99
+v 4 0 dc 5.0
+vin 1 0 dc 2.5 pulse (0 5 0 1n 1n 10n 25n)
+r1 1 2 100
+r2 3 4 10k
+*
+.control
+op
+tran 50p 50n
+plot v(1) v(2) v(3) v(4)
+plot v(t)
+.endc
+*
+.model vbic99 npn
++ LEVEL = 9 TREF = 27.0 RCX = 10.26
++ RCI = 0.001 VO = 0 GAMM = 0
++ HRCF = 0 RBX = 122.23 RBI = 0.001
++ RE = 17.61 RS = 1 RBP = 1
++ IS = 4.70047e-25 NF = 1.09575 NR = 1.02
++ FC = 0.9 CBEO = 0 CJE = 7e-15
++ PE = 0.75 ME = 0.33 AJE = -0.5
++ CBCO = 0 CJC = 1.1e-14 QCO = 0
++ CJEP = 0 PC = 0.75 MC = 0.33
++ AJC = -0.5 CJCP = 3e-15 PS = 0.75
++ MS = 0.33 AJS = -0.5 IBEI = 1.484e-23
++ WBE = 1 NEI = 1.302 IBEN = 6.096e-18
++ NEN = 2.081 IBCI = 5.618e-24 NCI = 1.11
++ IBCN = 3.297e-14 NCN = 2 AVC1 = 0
++ AVC2 = 0 ISP = 0 WSP = 1
++ NFP = 1 IBEIP = 0 IBENP = 0
++ IBCIP = 0 NCIP = 1 IBCNP = 0
++ NCNP = 2 VEF = 800 VER = 700
++ IKF = 0 IKR = 0 IKP = 0
++ TF = 2.3e-12 QTF = 0 XTF = 0
++ VTF = 0 ITF = 0 TR = 0
++ TD = 1e-15 KFN = 0 AFN = 1
++ BFN = 1 XRE = 2 XRBI = 2
++ XRCI = 2 XRS = 2 XVO = 0
++ EA = 1.1095 EAIE = 1.489271 EAIC = 1.489271
++ EAIS = 1.12 EANE = 1.489271 EANC = 1.489271
++ EANS = 1.12 XIS = 3 XII = 3
++ XIN = 3 TNF = 0 TAVC = 0
++ RTH = 159.177 CTH = 0 VRT = 0
++ ART = 0.1 CCSO = 0 QBM = 0
++ NKF = 0.5 XIKF = 0 XRCX = 2
++ XRBX = 2 XRBP = 0 ISRR = 1
++ XISR = 0 DEAR = 0 EAP = 1.12
++ VBBE = 0 NBBE = 1 IBBE = 1e-06
++ TVBBE1 = 0 TVBBE2 = 0 TNBBE = 0
+*
+.end
+
diff --git a/Windows/spice/examples/vbic/vbic_ac_par.sp b/Windows/spice/examples/vbic/vbic_ac_par.sp
new file mode 100644
index 00000000..c3f353f9
--- /dev/null
+++ b/Windows/spice/examples/vbic/vbic_ac_par.sp
@@ -0,0 +1,20 @@
+Ask for small signal values of vbic model
+
+.include Infineon_VBIC.lib
+
+v1 1 0 dc 5.0
+*rc 1 c 2k
+vb b 0 dc 0.6
+q1 1 b 0 M_BFP780
+
+.control
+save @q1[gm] @q1[go] @q1[gpi]
+save @q1[cbe] @q1[cbc]
+save @q1[qbe] @q1[qbc]
+dc v1 0.0 5 0.01
+plot @q1[gm] @q1[go] @q1[gpi]
+plot @q1[cbe] @q1[cbc]
+plot @q1[qbe] @q1[qbc]
+.endc
+
+.end