From 871480933a1c28f8a9fed4c4d34d06c439a7a422 Mon Sep 17 00:00:00 2001
From: Srikant Patnaik
Date: Sun, 11 Jan 2015 12:28:04 +0530
Subject: Moved, renamed, and deleted files

The original directory structure was scattered and unorganized.
Changes are basically to make it look like kernel structure.
---
 ANDROID_3.4.5/arch/x86/boot/pmjump.S | 77 ------------------------------------
 1 file changed, 77 deletions(-)
 delete mode 100644 ANDROID_3.4.5/arch/x86/boot/pmjump.S

(limited to 'ANDROID_3.4.5/arch/x86/boot/pmjump.S')

diff --git a/ANDROID_3.4.5/arch/x86/boot/pmjump.S b/ANDROID_3.4.5/arch/x86/boot/pmjump.S
deleted file mode 100644
index 3e0edc6d..00000000
--- a/ANDROID_3.4.5/arch/x86/boot/pmjump.S
+++ /dev/null
@@ -1,77 +0,0 @@
-/* ----------------------------------------------------------------------- *
- *
- *   Copyright (C) 1991, 1992 Linus Torvalds
- *   Copyright 2007 rPath, Inc. - All Rights Reserved
- *
- *   This file is part of the Linux kernel, and is made available under
- *   the terms of the GNU General Public License version 2.
- *
- * ----------------------------------------------------------------------- */
-
-/*
- * The actual transition into protected mode
- */
-
-#include <asm/boot.h>
-#include <asm/processor-flags.h>
-#include <asm/segment.h>
-#include <linux/linkage.h>
-
-	.text
-	.code16
-
-/*
- * void protected_mode_jump(u32 entrypoint, u32 bootparams);
- */
-GLOBAL(protected_mode_jump)
-	movl	%edx, %esi		# Pointer to boot_params table
-
-	xorl	%ebx, %ebx
-	movw	%cs, %bx
-	shll	$4, %ebx
-	addl	%ebx, 2f
-	jmp	1f			# Short jump to serialize on 386/486
-1:
-
-	movw	$__BOOT_DS, %cx
-	movw	$__BOOT_TSS, %di
-
-	movl	%cr0, %edx
-	orb	$X86_CR0_PE, %dl	# Protected mode
-	movl	%edx, %cr0
-
-	# Transition to 32-bit mode
-	.byte	0x66, 0xea		# ljmpl opcode
-2:	.long	in_pm32			# offset
-	.word	__BOOT_CS		# segment
-ENDPROC(protected_mode_jump)
-
-	.code32
-	.section ".text32","ax"
-GLOBAL(in_pm32)
-	# Set up data segments for flat 32-bit mode
-	movl	%ecx, %ds
-	movl	%ecx, %es
-	movl	%ecx, %fs
-	movl	%ecx, %gs
-	movl	%ecx, %ss
-	# The 32-bit code sets up its own stack, but this way we do have
-	# a valid stack if some debugging hack wants to use it.
-	addl	%ebx, %esp
-
-	# Set up TR to make Intel VT happy
-	ltr	%di
-
-	# Clear registers to allow for future extensions to the
-	# 32-bit boot protocol
-	xorl	%ecx, %ecx
-	xorl	%edx, %edx
-	xorl	%ebx, %ebx
-	xorl	%ebp, %ebp
-	xorl	%edi, %edi
-
-	# Set up LDTR to make Intel VT happy
-	lldt	%cx
-
-	jmpl	*%eax			# Jump to the 32-bit entrypoint
-ENDPROC(in_pm32)
-- 
cgit